hello/meson.build at main · NurOS-Linux/hello · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
project(
  'nuros-hello',
  'c',
  version: '2.1.0',
  license: 'GPL-3.0-or-later',
  meson_version: '>= 0.62.0',
  default_options: [
    'warning_level=2',
    'werror=false',
    'c_std=gnu11',
  ],
)

app_id = 'org.nuros.Hello'
gettext_package = meson.project_name()

prefix = get_option('prefix')
localedir = prefix / get_option('localedir')

config_h = configuration_data()
config_h.set_quoted('GETTEXT_PACKAGE', gettext_package)
config_h.set_quoted('LOCALEDIR', localedir)
config_h.set_quoted('VERSION', meson.project_version())

configure_file(
  output: 'config.h',
  configuration: config_h,
)

gnome = import('gnome')
i18n = import('i18n')

dependency('gtk4', version: '>= 4.10.0')
dependency('libadwaita-1', version: '>= 1.4.0')

glib_compile_resources = find_program('glib-compile-resources')

subdir('data')
subdir('po')
subdir('src')
subdir('tests')

gnome.post_install(
  gtk_update_icon_cache: true,
  glib_compile_schemas: true,
  update_desktop_database: true,
)