build.gradle

buildscript {
    repositories {
        mavenCentral()
        gradlePluginPortal()
    }
    dependencies {
        classpath "org.graceframework:grace-gradle-plugin:$graceVersion"
        classpath "io.github.gradle-nexus:publish-plugin:2.0.0"
    }
}

ext."signing.keyId" = project.hasProperty("signing.keyId") ? project.getProperty('signing.keyId') : System.getenv('SIGNING_KEY')
ext."signing.password" = project.hasProperty("signing.password") ? project.getProperty('signing.password') : System.getenv('SIGNING_PASSPHRASE')
ext."signing.secretKeyRingFile" = project.hasProperty("signing.secretKeyRingFile") ? project.getProperty('signing.secretKeyRingFile') : ("${System.properties['user.home']}${File.separator}.gnupg${File.separator}secring.gpg")
ext.isReleaseVersion = !projectVersion.endsWith("SNAPSHOT")

// Overriding GORM versions in Grace Bom
ext['grace-gorm.version'] = project.gormVersion
ext['grace-gorm-hibernate.version'] = project.gormHibernateVersion
ext['grace-plugin-hibernate.version'] = project.gormHibernateVersion

version = project.projectVersion
group = "org.graceframework.plugins"

apply plugin: "eclipse"
apply plugin: "idea"
apply plugin: "groovy"
apply plugin: "java-library"
apply plugin: "org.graceframework.grace-doc"
apply plugin: "org.graceframework.grace-plugin"
apply plugin: "io.github.gradle-nexus.publish-plugin"
apply plugin: "maven-publish"
apply plugin: "signing"

repositories {
    mavenCentral()
}

configurations {
    documentation
}

dependencies {
    api "org.liquibase:liquibase-core", {
        exclude group: 'javax.xml.bind', module: 'jaxb-api'
        exclude group: 'com.opencsv', module: 'opencsv'
    }
    api("org.liquibase.ext:liquibase-hibernate5") {
        exclude group: 'org.hibernate', module: 'hibernate-core'
        exclude group: 'org.hibernate', module: 'hibernate-entitymanager'
        exclude group: 'org.hibernate', module: 'hibernate-envers'
        exclude group: 'org.liquibase', module: 'liquibase-core'
        exclude group: 'org.liquibase', module: 'liquibase-commercial'
        exclude group: 'org.liquibase', module: 'liquibase-test-harness'
        exclude group: 'com.h2database', module: 'h2'
    }
    compileOnly("org.graceframework:grace-shell") {
        exclude group: 'org.slf4j', module: 'slf4j-simple'
    }
    api "org.apache.groovy:groovy-sql"

    compileOnly "org.graceframework:grace-boot"
    compileOnly "org.graceframework:grace-cli"
    compileOnly 'jakarta.servlet:jakarta.servlet-api'
    implementation "org.graceframework:grace-datastore-gorm"
    implementation "org.graceframework.plugins:hibernate"

    testImplementation "org.graceframework:grace-shell"
    testImplementation "org.graceframework.plugins:hibernate"

    testImplementation "org.graceframework:grace-test-support"
    testImplementation "org.mockito:mockito-core"
    testImplementation "com.h2database:h2"

    documentation "com.github.javaparser:javaparser-core:$javaParserCoreVersion"
    documentation "org.apache.groovy:groovy"
    documentation "org.apache.groovy:groovy-ant"
    documentation "org.apache.groovy:groovy-templates"
    documentation "org.apache.groovy:groovy-xml"
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
    withJavadocJar()
    withSourcesJar()
}

jar {
    enabled = true
    archiveClassifier.set('plugin')
    includeEmptyDirs = false
    exclude 'testapp/*.class', 'databasemigration/*.class'
}

def cleanTask = project.tasks.findByName('clean')
if (cleanTask == null) {
    task clean(type: Delete) {
        delete(buildDir)
    }
}
else {
    cleanTask.doLast {
        ant.delete(dir: 'build/docs')
    }
}

tasks.withType(Groovydoc) {
    group = 'Documentation'
    docTitle = "Grace Database Migration Plugin - ${project.version}"
    destinationDir = project.file('build/docs/manual/api')
    def files = []
    project.rootProject.subprojects
            .findAll { !it.name != 'docs' && !it.name.startsWith('examples') }
            .each { subproject ->
                if(subproject.file('src/main/groovy').exists()) {
                    files += subproject.files('src/main/groovy')
                }
                if(subproject.file('src/main/java').exists()) {
                    files += subproject.files('src/main/java')
                }
            }
    if (project.file('src/main/groovy').exists()) {
        files += project.files('src/main/groovy')
    }
    source = files
    classpath += configurations.documentation
}

docs {
    dependsOn groovydoc
    sourceDir = project.file('src/docs')
}

publishing {
    publications {
        maven(MavenPublication) {
            groupId = project.group
            artifactId = project.name
            version = project.version

            versionMapping {
                usage('java-api') {
                    fromResolutionOf('runtimeClasspath')
                }
                usage('java-runtime') {
                    fromResolutionResult()
                }
            }

            from components.java

            afterEvaluate {
                artifact source: "${project.sourceSets.main.groovy.classesDirectory.get()}/META-INF/grails-plugin.xml",
                        classifier: "plugin",
                        extension: 'xml'
            }
            pom {
                name = "Grace Database Migration Plugin"
                description = "Grace Database Migration"
                url = 'https://github.com/graceframework/grace-database-migration'
                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'https://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
                developers {
                    developer {
                        id = 'rainboyan'
                        name = 'Michael Yan'
                        email = 'rain@rainboyan.com'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com/graceframework/grace-database-migration.git'
                    developerConnection = 'scm:git:ssh://github.com:graceframework/grace-database-migration.git'
                    url = 'https://github.com/graceframework/grace-database-migration'
                }
            }
        }
    }
}

nexusPublishing {
    packageGroup = 'org.graceframework.plugins'
    repositories {
        sonatype {
            def mavenUser = System.getenv("MAVEN_CENTRAL_USER") ?: project.hasProperty("mavenCentralUsername") ? project.mavenCentralUsername : ''
            def mavenPass = System.getenv("MAVEN_CENTRAL_PASSWORD") ?: project.hasProperty("mavenCentralPassword") ? project.mavenCentralPassword : ''
            nexusUrl = uri("https://ossrh-staging-api.central.sonatype.com/service/local/")
            snapshotRepositoryUrl = uri("https://central.sonatype.com/repository/maven-snapshots/")
            username = mavenUser
            password = mavenPass
        }
    }
}

afterEvaluate {
    signing {
        required = isReleaseVersion && gradle.taskGraph.hasTask("publish")
        sign publishing.publications.maven
    }
}