forge-example/build.gradle at main · mc-modding/forge-example · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
buildscript {
    /* Репозитории Gradle-плагинов */
    repositories {
        gradlePluginPortal()
        mavenCentral()
        maven {
            name = "forge"
            url = uri("https://maven.minecraftforge.net")
        }
        maven {
            name = "jitpack"
            url = uri("https://jitpack.io")
        }
        maven {
            name = "github"
            url = uri("https://github.com/juanmuscaria/maven/raw/master")
        }
    }
    dependencies {
        classpath ('com.anatawa12.forge:ForgeGradle:1.2-1.1.+') {
           changing = true
       }
    }
}

repositories {
    flatDir {
        dirs 'deps'
    }
}

apply plugin: 'idea'
apply plugin: 'java'
apply plugin: 'forge'

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
}

java {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
}

/* Вспомогательные конфиги для IDEA */
idea {
    module {
        inheritOutputDirs = true // Складываем *.class и assets в одну директорию, из разных Forge читать не будет
        excludeDirs += file('./run') // Исключаем директории из индексации
    }
}

minecraft {
    version = '1.7.10-10.13.4.1614-1.7.10' // Версия Forge
    //mappings = "stable_12" // Версия маппингов Minecraft для подготовки среды разработки
}

processResources {
    duplicatesStrategy = DuplicatesStrategy.INCLUDE

    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
        expand 'version': project.version, 'mcversion': project.minecraft.version
    }

    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

/* Dev версия мода без обфускации MC */
tasks.register('devJar', Jar) {
    archiveClassifier.set('dev')
    manifest.from(jar.manifest)
    from sourceSets.main.output
}

artifacts {
    archives devJar
}