Is this the best way to implement the equivalent of C-k in ido-mode?

[mgalgs]

I recently moved from ido to consult + vertico and am really missing the ability to kill buffers while switching buffers. in ido you can kill the currently selected candidate buffer with C-k.

I've implemented something similar and it's working okay. The main problem is that the whole vertico session gets restarted after killing, so it's not very smooth...

Is there anything built-in to vertico for this that I'm missing? If not, any suggestions for improving the below code to avoid losing the vertico session?

(use-package vertico
  :ensure t
  :custom
  (vertico-cycle t)
  :init
  (vertico-mode)
  :config
  (defun m/kill-current-consult-buffer ()
    "Kill the currently selected buffer in `consult-buffer'."
    (interactive)
    (let* ((candidate (vertico--candidate))
           (multi-cat (get-text-property 0 'multi-category candidate))
           (buf-name (when (consp multi-cat) (cdr multi-cat)))
           (buf (and buf-name (get-buffer buf-name))))
      (if (and buf (buffer-live-p buf))
          (progn
            (kill-buffer buf)
            (message "Killed buffer: %s" buf-name)
            (call-interactively 'consult-buffer))
        (message "No live buffer found to kill"))))
  :bind
  (:map
   vertico-map
   ("C-l" . vertico-directory-up)
   ("C-k" . m/kill-current-consult-buffer)))

Thanks!

[mgalgs]

I know I can do this with embark, but that's two keystrokes (one to invoke embark, and a second to select the "kill" action from embark).

[minad]

Yes, Embark is the answer. You should really be using it. It enables much more but you can get into it step by step.

Regarding the keystrokes - In eMACs you can always define keyboard MACros to turn two keystrokes into one. This has been asked surprisingly many times. ;)

[mgalgs]

Regarding the keystrokes - In eMACs you can always define keyboard MACros to turn two keystrokes into one. This has been asked surprisingly many times. ;)

Lol I guess I deserved that... Yes I'm well aware 😅

[mgalgs]

Here's what I've come up with:

(use-package vertico
  :ensure t
  :custom
  (vertico-cycle t)
  :init
  (vertico-mode)
  :config
  (defun m/kill-current-buffer-embark (&optional arg)
    "Kill the current buffer candidate using Embark."
    (interactive "P")
    (let ((kill-buffer-query-functions (delq 'process-kill-buffer-query-function
                                             kill-buffer-query-functions))
          (embark-default-action-overrides '((buffer . kill-buffer)))
          ; These next two suppress confirmations from embark itself
          embark-pre-action-hooks
          embark-quit-after-action)
      (embark-dwim arg)))
  (defvar m/consult-buffer-map
    (let ((map (make-sparse-keymap)))
      (define-key map (kbd "C-k") #'m/kill-current-buffer-embark)
      map))
  (consult-customize consult-buffer :keymap m/consult-buffer-map)
  :bind
  (:map
   vertico-map
   ("C-l" . vertico-directory-up)))

This performs the buffer killing via embark, without confirmation, and also moves the keybinding to be consult-buffer specific via consult-customize. Seems to be working well but I'm open to further improvements!