polyphony/justfile at main · penso/polyphony · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
default:
    @just --list

nightly_toolchain := "nightly-2025-11-30"

format:
    cargo +{{nightly_toolchain}} fmt --all

format-check:
    cargo +{{nightly_toolchain}} fmt --all -- --check

lockfile-check:
    cargo metadata --locked --format-version=1 > /dev/null

lint: lockfile-check
    cargo +{{nightly_toolchain}} clippy --workspace --all-features --all-targets -- -D warnings

test:
    bash ./scripts/ci/with-sanitized-env.sh cargo +{{nightly_toolchain}} test --workspace --exclude polyphony-cli

test-e2e suite="":
    @if [ -z "{{suite}}" ]; then \
        for s in e2e_daemon_control e2e_dispatch e2e_headless e2e_retry_and_data e2e_scheduling; do \
            echo "==> Running $s"; \
            bash ./scripts/ci/with-sanitized-env.sh cargo +{{nightly_toolchain}} test --locked -p polyphony-cli --test "$s" -- --nocapture || exit 1; \
        done; \
    else \
        bash ./scripts/ci/with-sanitized-env.sh cargo +{{nightly_toolchain}} test --locked -p polyphony-cli --test {{suite}} -- --nocapture; \
    fi

test-raw:
    cargo +{{nightly_toolchain}} test --workspace

install:
    mkdir -p "$HOME/.local/bin"
    cargo +{{nightly_toolchain}} build --release -p polyphony-cli
    install -m 755 target/release/polyphony "$HOME/.local/bin/polyphony"

httpd port="8080":
    POLYPHONY_DAEMON__LISTEN_PORT={{port}} cargo +{{nightly_toolchain}} run -p polyphony-cli

httpd-only port="8080":
    POLYPHONY_DAEMON__LISTEN_PORT={{port}} cargo +{{nightly_toolchain}} run -p polyphony-cli -- --no-tui

docs-build:
    mdbook build docs

docs-serve:
    mdbook serve docs --open

website-serve:
    python3 -m http.server 5002 --directory website

schema-github:
    ./scripts/refresh_github_schema.sh

schema-linear:
    ./scripts/refresh_linear_schema.sh

schema-refresh:
    just schema-github
    just schema-linear

changelog:
    git-cliff --config cliff.toml --output CHANGELOG.md

changelog-unreleased:
    git-cliff --config cliff.toml --unreleased

changelog-release version:
    git-cliff --config cliff.toml --unreleased --tag "{{version}}" --strip all

release:
    ./scripts/ci/release-tag.sh

release-push:
    ./scripts/ci/release-tag.sh --push