cpp-packed-hashtable/CMakeLists.txt at main · pr0g/cpp-packed-hashtable · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
cmake_minimum_required(VERSION 3.28)
project(thh-packed-hashtable LANGUAGES CXX)

include(FetchContent)
include(GNUInstallDirs)

FetchContent_Declare(
  thh-handle-vector
  GIT_REPOSITORY https://github.com/pr0g/cpp-handle-container.git
  GIT_TAG fca525ac784c9b714bfd956821fa6410244561b6)
FetchContent_MakeAvailable(thh-handle-vector)

add_library(${PROJECT_NAME} INTERFACE)
target_include_directories(
  ${PROJECT_NAME}
  INTERFACE $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
            $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
target_compile_features(${PROJECT_NAME} INTERFACE cxx_std_17)
target_link_libraries(${PROJECT_NAME} INTERFACE thh-handle-vector)

option(THH_PACKED_HASHTABLE_ENABLE_MEMORY "Enable memory profiling" OFF)
option(THH_PACKED_HASHTABLE_ENABLE_TEST "Enable testing" OFF)
option(THH_PACKED_HASHTABLE_ENABLE_BENCH "Enable benchmarking" OFF)
option(THH_PACKED_HASHTABLE_ENABLE_ECS "Enable ECS experiment" OFF)

if(THH_PACKED_HASHTABLE_ENABLE_MEMORY)
  add_executable(${PROJECT_NAME}-memory)
  target_sources(${PROJECT_NAME}-memory PRIVATE memory.cpp)
  target_link_libraries(${PROJECT_NAME}-memory PRIVATE ${PROJECT_NAME})
  target_compile_features(${PROJECT_NAME}-memory PRIVATE cxx_std_17)
endif()

if(THH_PACKED_HASHTABLE_ENABLE_ECS)
  add_executable(${PROJECT_NAME}-ecs)
  target_sources(${PROJECT_NAME}-ecs PRIVATE ecs.cpp)
  target_link_libraries(${PROJECT_NAME}-ecs PRIVATE ${PROJECT_NAME})
  target_compile_features(${PROJECT_NAME}-ecs PRIVATE cxx_std_17)
endif()

if(THH_PACKED_HASHTABLE_ENABLE_TEST)
  FetchContent_Declare(
    doctest
    GIT_REPOSITORY https://github.com/onqtam/doctest.git
    GIT_TAG 1da23a3e8119ec5cce4f9388e91b065e20bf06f5)
  FetchContent_MakeAvailable(doctest)
  add_executable(${PROJECT_NAME}-test)
  target_sources(${PROJECT_NAME}-test PRIVATE test.cpp)
  target_link_libraries(${PROJECT_NAME}-test ${PROJECT_NAME} doctest)
  target_compile_options(
    ${PROJECT_NAME}-test
    PRIVATE $<$<COMPILE_LANG_AND_ID:CXX,MSVC>:/W4
            /WX>
            $<$<COMPILE_LANG_AND_ID:CXX,AppleClang,Clang>:
            -Weverything
            -Wall
            -Wextra
            -pedantic
            -Wno-c++98-compat;-Wno-
            -Wno-sign-conversion;-Wno->
            $<$<COMPILE_LANG_AND_ID:CXX,GNU>:-Wall
            -Wextra
            -pedantic>)
  target_compile_features(${PROJECT_NAME}-test PRIVATE cxx_std_17)
endif()

if(THH_PACKED_HASHTABLE_ENABLE_BENCH)
  set(CMAKE_CXX_STANDARD 17)
  set(BENCHMARK_ENABLE_TESTING OFF)
  FetchContent_Declare(
    benchmark
    GIT_REPOSITORY https://github.com/google/benchmark.git
    GIT_TAG main)
  set(ABSL_PROPAGATE_CXX_STD ON)
  FetchContent_Declare(
    abseil
    GIT_REPOSITORY https://github.com/abseil/abseil-cpp.git
    GIT_TAG 0e5031d3c00d8a482cd5705b5d006518447f39da)
  FetchContent_Declare(
    robin-hood
    GIT_REPOSITORY https://github.com/martinus/robin-hood-hashing.git
    GIT_TAG 7697343363af4cc3f42cab17be49e6af9ab181e2)
  FetchContent_MakeAvailable(benchmark abseil robin-hood)
  add_executable(${PROJECT_NAME}-bench)
  target_sources(${PROJECT_NAME}-bench PRIVATE bench.cpp)
  target_link_libraries(
    ${PROJECT_NAME}-bench PRIVATE ${PROJECT_NAME} benchmark absl::flat_hash_map
                                  robin_hood)
  target_compile_options(
    ${PROJECT_NAME}-bench
    PRIVATE $<$<COMPILE_LANG_AND_ID:CXX,MSVC>:/W4 /WX>
            $<$<COMPILE_LANG_AND_ID:CXX,AppleClang,Clang,GNU>: -Wall -Wextra
            -pedantic>)
  target_compile_features(${PROJECT_NAME}-bench PRIVATE cxx_std_17)
endif()

install(TARGETS ${PROJECT_NAME} EXPORT ${PROJECT_NAME}-config)

install(DIRECTORY ${CMAKE_CURRENT_LIST_DIR}/include/${PROJECT_NAME}
        DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})

install(
  EXPORT ${PROJECT_NAME}-config
  NAMESPACE ${PROJECT_NAME}::
  FILE ${PROJECT_NAME}-targets.cmake
  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME})

configure_file(${PROJECT_NAME}-config.cmake.in ${PROJECT_NAME}-config.cmake
               @ONLY)
install(FILES "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}-config.cmake"
        DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME})