simde/CMakeLists.txt at master · simd-everywhere/simde · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
cmake_minimum_required(VERSION 3.22)

project(
    simde
    DESCRIPTION
        "Implementations of SIMD instruction sets for systems which don't natively support them."
    HOMEPAGE_URL "https://github.com/simd-everywhere/simde"
    LANGUAGES C CXX
    VERSION 0.8.4
)

# Options
option(SIMDE_TEST_CMAKE_PACKAGING "Test cmake packaging" ${PROJECT_IS_TOP_LEVEL})

# The main simde library
add_library(simde INTERFACE)
add_library(simde::simde ALIAS simde)

target_compile_features(simde INTERFACE c_std_99)

target_include_directories(
    simde
    INTERFACE
        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
        $<INSTALL_INTERFACE:include>
)

if(SIMDE_TEST_CMAKE_PACKAGING)
    include(CTest)
    enable_testing()
    add_subdirectory(test/cmake-packaging)
endif()

include(GNUInstallDirs)

# Install headers
install(DIRECTORY simde DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})

# Export targets
install(TARGETS simde EXPORT simde-targets)

# Package Configuration
include(CMakePackageConfigHelpers)

write_basic_package_version_file(
    ${CMAKE_CURRENT_BINARY_DIR}/simde-config-version.cmake
    VERSION ${PROJECT_VERSION}
    COMPATIBILITY SameMajorVersion
)

file(
    WRITE
    ${CMAKE_CURRENT_BINARY_DIR}/simde-config.cmake.in
    "@PACKAGE_INIT@\n"
    "include(\"\${CMAKE_CURRENT_LIST_DIR}/simde-config-targets.cmake\")\n"
)

configure_package_config_file(
    ${CMAKE_CURRENT_BINARY_DIR}/simde-config.cmake.in
    ${CMAKE_CURRENT_BINARY_DIR}/simde-config.cmake
    INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/simde
    NO_SET_AND_CHECK_MACRO
    NO_CHECK_REQUIRED_COMPONENTS_MACRO
)

install(
    FILES
        ${CMAKE_CURRENT_BINARY_DIR}/simde-config.cmake
        ${CMAKE_CURRENT_BINARY_DIR}/simde-config-version.cmake
    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/simde
)

install(
    EXPORT simde-targets
    FILE simde-config-targets.cmake
    NAMESPACE simde::
    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/simde
)