CMakeLists.txt

CMAKE_MINIMUM_REQUIRED(VERSION 3.10)
PROJECT(DGalerkin VERSION 1.3.6)

INCLUDE(CTest)

# put all generated files in a single folder (required in windows for exe linked to dlls)
SET(LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin CACHE PATH "")
SET(EXECUTABLE_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin CACHE PATH "")
MARK_AS_ADVANCED(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)

# build type is "" by default in Linux
# IF(NOT CMAKE_BUILD_TYPE)
SET(CMAKE_BUILD_TYPE "Release" CACHE STRING "" FORCE)

# ENDIF()

# enable C++11/C++17
SET(CMAKE_CXX_STANDARD 17) # newer way to set C++11/17 (requires cmake>3.1)
SET(CMAKE_CXX_STANDARD_REQUIRED ON)

IF(UNIX AND CMAKE_CXX_COMPILER_ID STREQUAL GNU)
    ADD_DEFINITIONS(-D_GLIBCXX_USE_CXX11_ABI=1)
ELSEIF(CMAKE_CXX_COMPILER_ID MATCHES MSVC)
    ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_WARNINGS)
    ADD_DEFINITIONS(-D_USE_MATH_DEFINES)
ENDIF()

# MPI (optional) — enable with -DDG_USE_MPI=ON
OPTION(DG_USE_MPI "Enable MPI parallelization" ON)
IF(DG_USE_MPI)
    FIND_PACKAGE(MPI REQUIRED)
    IF(MPI_CXX_FOUND)
        MESSAGE(STATUS "MPI found: ${MPI_CXX_COMPILER}")
        ADD_DEFINITIONS(-DDG_USE_MPI)
        INCLUDE_DIRECTORIES(${MPI_CXX_INCLUDE_DIRS})
    ENDIF()
ENDIF()

# find gmsh-sdk
# gmsh.h
SET(GMSH_INCLUDE_DIRS ${PROJECT_SOURCE_DIR}/3rdParty/gmsh/include)
IF(APPLE)
    SET(GMSH_LIBRARIES ${PROJECT_SOURCE_DIR}/3rdParty/gmsh/lib/libgmsh.dylib)
ELSE()
    SET(GMSH_LIBRARIES ${PROJECT_SOURCE_DIR}/3rdParty/gmsh/lib/libgmsh.so)
ENDIF()
SET(GMSH_EXECUTABLE ${PROJECT_SOURCE_DIR}/3rdParty/gmsh/bin/gmsh)

FIND_PATH(GMSH_INCLUDE_DIRS NAMES "gmsh.h")
MESSAGE(STATUS "GMSH_INCLUDE_DIRS=" ${GMSH_INCLUDE_DIRS})

if(NOT GMSH_INCLUDE_DIRS)
    MESSAGE(FATAL_ERROR "gmsh.h not found!")
ENDIF()

INCLUDE_DIRECTORIES(${GMSH_INCLUDE_DIRS})

# libgmsh.so
FIND_LIBRARY(GMSH_LIBRARIES gmsh
    HINTS ${PROJECT_SOURCE_DIR}/3rdParty/gmsh/lib
    NO_DEFAULT_PATH)
MESSAGE(STATUS "GMSH_LIBRARIES=" ${GMSH_LIBRARIES})

IF(NOT GMSH_LIBRARIES)
    message(FATAL_ERROR "gmsh library not found!")
ENDIF()

# gmsh.exe
FIND_PROGRAM(GMSH_EXECUTABLE gmsh)
MESSAGE(STATUS "GMSH_EXECUTABLE=" ${GMSH_EXECUTABLE})

IF(NOT GMSH_EXECUTABLE)
    message(FATAL_ERROR "gmsh executable not found!")
ENDIF()

# Lapack
FIND_PACKAGE(BLAS)
FIND_PACKAGE(LAPACK)
MESSAGE(STATUS "LAPACK=" ${LAPACK_LIBRARIES})

if(LAPACK_FOUND AND BLAS_FOUND)
    set(LAPACKBLAS_LIBRARIES ${BLAS_LIBRARIES} ${LAPACK_LIBRARIES})
endif()

# Eigen
# SET(EIGEN_INCLUDE_DIRS ${PROJECT_SOURCE_DIR}/3rdParty/eigen)
# FIND_PATH(EIGEN_INCLUDE_DIRS NAMES "Eigen/Eigen")
# MESSAGE(STATUS "EIGEN_INCLUDE_DIRS=" ${EIGEN_INCLUDE_DIRS})

# if(NOT EIGEN_INCLUDE_DIRS)
#     MESSAGE(FATAL_ERROR "Eigen not found!")
# ENDIF()

# INCLUDE_DIRECTORIES(${EIGEN_INCLUDE_DIRS})
# FIND_PACKAGE(EIGEN REQUIRED)
IF(APPLE)
    # Homebrew paths: Apple Silicon (/opt/homebrew) or Intel (/usr/local)
    FIND_PATH(EIGEN_INCLUDE_DIRS NAMES "Eigen/Eigen"
        HINTS
            /opt/homebrew/include/eigen3
            /usr/local/include/eigen3
    )
ELSE()
    SET(EIGEN_INCLUDE_DIRS "/usr/include/eigen3" CACHE PATH "Eigen directory override" FORCE)
    FIND_PATH(EIGEN_INCLUDE_DIRS NAMES "Eigen/Eigen")
ENDIF()
MESSAGE(STATUS "EIGEN_INCLUDE_DIRS=" ${EIGEN_INCLUDE_DIRS})
if(NOT EIGEN_INCLUDE_DIRS)
    MESSAGE(FATAL_ERROR "Eigen not found!")
ENDIF()
INCLUDE_DIRECTORIES(${EIGEN_INCLUDE_DIRS})

# SET(EIGEN_INCLUDE_DIRS "/usr/share/eigen3/cmake" CACHE PATH "Eigen directory override" FORCE)

# OpenMP
# On macOS with Apple Clang, libomp must be installed via Homebrew (brew install libomp)
IF(APPLE)
    FIND_PROGRAM(BREW_EXECUTABLE brew)
    IF(BREW_EXECUTABLE)
        EXECUTE_PROCESS(COMMAND ${BREW_EXECUTABLE} --prefix libomp
            OUTPUT_VARIABLE LIBOMP_PREFIX OUTPUT_STRIP_TRAILING_WHITESPACE)
        IF(LIBOMP_PREFIX)
            SET(OpenMP_C_FLAGS   "-Xpreprocessor -fopenmp -I${LIBOMP_PREFIX}/include")
            SET(OpenMP_CXX_FLAGS "-Xpreprocessor -fopenmp -I${LIBOMP_PREFIX}/include")
            SET(OpenMP_C_LIB_NAMES "omp")
            SET(OpenMP_CXX_LIB_NAMES "omp")
            SET(OpenMP_omp_LIBRARY "${LIBOMP_PREFIX}/lib/libomp.dylib")
        ENDIF()
    ENDIF()
ENDIF()

FIND_PACKAGE(OpenMP REQUIRED)

if(OPENMP_FOUND)
    message("OpenMP found")
    set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${OpenMP_C_FLAGS}")
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${OpenMP_CXX_FLAGS}")
    set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${OpenMP_EXE_LINKER_FLAGS}")
endif()

# VTK
IF(NOT APPLE)
    SET(VTK_DIR "/usr/lib/x86_64-linux-gnu/cmake/vtk-9.1" CACHE PATH "VTK directory override" FORCE)
ENDIF()
FIND_PACKAGE(VTK COMPONENTS IOXML REQUIRED)

SET(WAVE_INCLUDE src/wave)
INCLUDE_DIRECTORIES(${WAVE_INCLUDE})

SET(WAVE_LD ${PROJECT_SOURCE_DIR}/build/bin)
LINK_DIRECTORIES(${WAVE_LD})

IF(APPLE)
    LINK_DIRECTORIES(/opt/homebrew/lib)
ENDIF()

SET(PARTITIONER_LIBRARIES "")
SET(PARTITIONER_HINT_INCLUDE_DIRS
    ${PROJECT_SOURCE_DIR}/3rdParty/METIS/install/include
    ${PROJECT_SOURCE_DIR}/3rdParty/ParMETIS/install/include
    ${PROJECT_SOURCE_DIR}/3rdParty/GKlib/install/include
    /opt/homebrew/include
    /usr/local/include
    /usr/include
)
SET(PARTITIONER_HINT_LIBRARY_DIRS
    ${PROJECT_SOURCE_DIR}/3rdParty/METIS/install/lib
    ${PROJECT_SOURCE_DIR}/3rdParty/ParMETIS/install/lib
    ${PROJECT_SOURCE_DIR}/3rdParty/GKlib/install/lib
    /opt/homebrew/lib
    /usr/local/lib
    /usr/lib
    /usr/lib/x86_64-linux-gnu
)

FIND_PATH(METIS_INCLUDE_DIR NAMES metis.h
    HINTS ${PARTITIONER_HINT_INCLUDE_DIRS}
)
FIND_LIBRARY(METIS_LIBRARY NAMES metis
    HINTS ${PARTITIONER_HINT_LIBRARY_DIRS}
)
IF(METIS_INCLUDE_DIR AND METIS_LIBRARY)
    MESSAGE(STATUS "METIS include: ${METIS_INCLUDE_DIR}")
    MESSAGE(STATUS "METIS library: ${METIS_LIBRARY}")
    INCLUDE_DIRECTORIES(${METIS_INCLUDE_DIR})
    ADD_DEFINITIONS(-DDG_HAS_METIS)
    LIST(APPEND PARTITIONER_LIBRARIES ${METIS_LIBRARY})
ELSE()
    MESSAGE(STATUS "METIS not found: direct METIS API backend disabled")
ENDIF()

FIND_PATH(SCOTCH_INCLUDE_DIR NAMES scotch.h
    HINTS ${PARTITIONER_HINT_INCLUDE_DIRS}
)
FIND_LIBRARY(SCOTCH_LIBRARY NAMES scotch
    HINTS ${PARTITIONER_HINT_LIBRARY_DIRS}
)
FIND_LIBRARY(SCOTCHERR_LIBRARY NAMES scotcherr scotcherrexit
    HINTS ${PARTITIONER_HINT_LIBRARY_DIRS}
)
IF(SCOTCH_INCLUDE_DIR AND SCOTCH_LIBRARY)
    MESSAGE(STATUS "SCOTCH include: ${SCOTCH_INCLUDE_DIR}")
    MESSAGE(STATUS "SCOTCH library: ${SCOTCH_LIBRARY}")
    INCLUDE_DIRECTORIES(${SCOTCH_INCLUDE_DIR})
    ADD_DEFINITIONS(-DDG_HAS_SCOTCH)
    LIST(APPEND PARTITIONER_LIBRARIES ${SCOTCH_LIBRARY})
    IF(SCOTCHERR_LIBRARY)
        LIST(APPEND PARTITIONER_LIBRARIES ${SCOTCHERR_LIBRARY})
    ENDIF()
ELSE()
    MESSAGE(STATUS "SCOTCH not found: direct SCOTCH API backend disabled")
ENDIF()

IF(DG_USE_MPI)
    FIND_PATH(PARMETIS_INCLUDE_DIR NAMES parmetis.h
        HINTS ${PARTITIONER_HINT_INCLUDE_DIRS}
    )
    FIND_LIBRARY(PARMETIS_LIBRARY NAMES parmetis
        HINTS ${PARTITIONER_HINT_LIBRARY_DIRS}
    )
    FIND_LIBRARY(GKLIB_LIBRARY NAMES GKlib gklib
        HINTS ${PARTITIONER_HINT_LIBRARY_DIRS}
    )

    IF(PARMETIS_INCLUDE_DIR AND PARMETIS_LIBRARY)
        MESSAGE(STATUS "ParMETIS include: ${PARMETIS_INCLUDE_DIR}")
        MESSAGE(STATUS "ParMETIS library: ${PARMETIS_LIBRARY}")
        INCLUDE_DIRECTORIES(${PARMETIS_INCLUDE_DIR})
        ADD_DEFINITIONS(-DDG_HAS_PARMETIS)
        LIST(APPEND PARTITIONER_LIBRARIES ${PARMETIS_LIBRARY})
        IF(GKLIB_LIBRARY)
            LIST(APPEND PARTITIONER_LIBRARIES ${GKLIB_LIBRARY})
        ENDIF()
        IF(METIS_LIBRARY)
            LIST(APPEND PARTITIONER_LIBRARIES ${METIS_LIBRARY})
        ENDIF()
    ELSE()
        MESSAGE(STATUS "ParMETIS not found: direct ParMETIS API backend disabled")
    ENDIF()
ENDIF()

# Libraries
INCLUDE_DIRECTORIES(include)

# Sources
ADD_SUBDIRECTORY(src/wave)
ADD_SUBDIRECTORY(src)